SharePoint @ Big Scholar

Here's a high overview of how to complete this along with the names of the files required to do this. Most of these files are available from the microsoft site. Just do a google search for the file name and you will be redirected to the download pages. Some files will require licensing (eg. Windows 2003 Server, MOSS and Visual Studio)

1. Install Windows server 2003 64 bit with ISO (SW_CD_Windows_Svr_Std_2003_R2_64-BIT_English_-2_x64_R2_CD1_ISO_MLF_X12-58050.ISO)
2. Install Windows Server 2003 SP2 (WindowsServer2003.WindowsXP-KB914961-SP2-x64-ENU.exe)
3. Install Windows Installer 64bit (WindowsServer2003-KB942288-v4-x64.exe)
4. Install .net Framework 2.0 SP2 64 bit (NetFx20SP2_x64.exe)
5. Install SQL Server Express 64 bit (SQLEXPR_x64_ENU.exe)
6. Install .net 3.5 (dotNetFx35setup.exe)
7. Install SharePoint 64 bit (OfficeServerwithSP1.exe)
8. Install Visual Studio 2008 from CD
9. Upgrade Visual Studio to SP1 (VS90sp1-KB945140-ENU.exe)
10. Install Visual Studio Extensions (VSeWSSv13_AMD64_Build-433.exe)
11. Install PowerShell 64 bit (WindowsServer2003.WindowsXP-KB926139-v2-x64-ENU.exe)
12. Install SQL Server Management Studio Express 64-bit (SQLManagementStudio_x64_ENU.exe)

Optional: Install IE8 (IE8-WindowsServer2003-x64-ENU.exe)

Here's some code that you can copy and paste into XSLT to see the raw xml being passed into the xsl transformation. I got this code from xmlportfolio.com, so please leave the copyrights there if you are planning on using this code:

<!--
Copyright (c) 2001-2004, Evan Lenz
All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:

    * Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
    * Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
    * Neither the name of XMLPortfolio.com nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.

     THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
-->
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output omit-xml-declaration="yes"/>

  <xsl:param name="use-empty-syntax" select="true()"/>
  <xsl:param name="exclude-unused-prefixes" select="true()"/>

  <xsl:param name="start-tag-start"     select="'&lt;'"/>
  <xsl:param name="start-tag-end"       select="'>'"/>
  <xsl:param name="empty-tag-end"       select="'/>'"/>
  <xsl:param name="end-tag-start"       select="'&lt;/'"/>
  <xsl:param name="end-tag-end"         select="'>'"/>
  <xsl:param name="space"               select="' '"/>
  <xsl:param name="ns-decl"             select="'xmlns'"/>
  <xsl:param name="colon"               select="':'"/>
  <xsl:param name="equals"              select="'='"/>
  <xsl:param name="attribute-delimiter" select="'&quot;'"/>
  <xsl:param name="comment-start"       select="'&lt;!--'"/>
  <xsl:param name="comment-end"         select="'-->'"/>
  <xsl:param name="pi-start"            select="'&lt;?'"/>
  <xsl:param name="pi-end"              select="'?>'"/>

  <xsl:template name="xml-to-string">
    <xsl:param name="node-set" select="."/>
    <xsl:apply-templates select="$node-set" mode="xml-to-string">
      <xsl:with-param name="depth" select="1"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="/" name="xml-to-string-root-rule">
    <xsl:call-template name="xml-to-string"/>
  </xsl:template>

  <xsl:template match="/" mode="xml-to-string">
    <xsl:param name="depth"/>
    <xsl:apply-templates mode="xml-to-string">
      <xsl:with-param name="depth" select="$depth"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="*" mode="xml-to-string">
    <xsl:param name="depth"/>
    <xsl:variable name="element" select="."/>
    <xsl:value-of select="$start-tag-start"/>
    <xsl:call-template name="element-name">
      <xsl:with-param name="text" select="name()"/>
    </xsl:call-template>
    <xsl:apply-templates select="@*" mode="xml-to-string"/>
    <xsl:for-each select="namespace::*">
      <xsl:call-template name="process-namespace-node">
        <xsl:with-param name="element" select="$element"/>
        <xsl:with-param name="depth" select="$depth"/>
      </xsl:call-template>
    </xsl:for-each>
    <xsl:choose>
      <xsl:when test="node() or not($use-empty-syntax)">
        <xsl:value-of select="$start-tag-end"/>
        <xsl:apply-templates mode="xml-to-string">
          <xsl:with-param name="depth" select="$depth + 1"/>
        </xsl:apply-templates>
        <xsl:value-of select="$end-tag-start"/>
        <xsl:call-template name="element-name">
          <xsl:with-param name="text" select="name()"/>
        </xsl:call-template>
        <xsl:value-of select="$end-tag-end"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$empty-tag-end"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template name="process-namespace-node">
    <xsl:param name="element"/>
    <xsl:param name="depth"/>
    <xsl:variable name="declaredAbove">
      <xsl:call-template name="isDeclaredAbove">
        <xsl:with-param name="depth" select="$depth - 1"/>
        <xsl:with-param name="element" select="$element/.."/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:if test="(not($exclude-unused-prefixes) or ($element | $element//@* | $element//*)[namespace-uri()=current()]) and not(string($declaredAbove)) and name()!='xml'">
      <xsl:value-of select="$space"/>
      <xsl:value-of select="$ns-decl"/>
      <xsl:if test="name()">
        <xsl:value-of select="$colon"/>
        <xsl:call-template name="ns-prefix">
          <xsl:with-param name="text" select="name()"/>
        </xsl:call-template>
      </xsl:if>
      <xsl:value-of select="$equals"/>
      <xsl:value-of select="$attribute-delimiter"/>
      <xsl:call-template name="ns-uri">
        <xsl:with-param name="text" select="string(.)"/>
      </xsl:call-template>
      <xsl:value-of select="$attribute-delimiter"/>
    </xsl:if>
  </xsl:template>

  <xsl:template name="isDeclaredAbove">
    <xsl:param name="element"/>
    <xsl:param name="depth"/>
    <xsl:if test="$depth > 0">
      <xsl:choose>
        <xsl:when test="$element/namespace::*[name(.)=name(current()) and .=current()]">1</xsl:when>
        <xsl:when test="$element/namespace::*[name(.)=name(current())]"/>
        <xsl:otherwise>
          <xsl:call-template name="isDeclaredAbove">
            <xsl:with-param name="depth" select="$depth - 1"/>
            <xsl:with-param name="element" select="$element/.."/>
          </xsl:call-template>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:if>
  </xsl:template>

  <xsl:template match="@*" mode="xml-to-string">
    <xsl:value-of select="$space"/>
    <xsl:call-template name="attribute-name">
      <xsl:with-param name="text" select="name()"/>
    </xsl:call-template>
    <xsl:value-of select="$equals"/>
    <xsl:value-of select="$attribute-delimiter"/>
    <xsl:call-template name="attribute-value">
      <xsl:with-param name="text" select="string(.)"/>
    </xsl:call-template>
    <xsl:value-of select="$attribute-delimiter"/>
  </xsl:template>

  <xsl:template match="comment()" mode="xml-to-string">
    <xsl:value-of select="$comment-start"/>
    <xsl:call-template name="comment-text">
      <xsl:with-param name="text" select="string(.)"/>
    </xsl:call-template>
    <xsl:value-of select="$comment-end"/>
  </xsl:template>

  <xsl:template match="processing-instruction()" mode="xml-to-string">
    <xsl:value-of select="$pi-start"/>
    <xsl:call-template name="pi-target">
      <xsl:with-param name="text" select="name()"/>
    </xsl:call-template>
    <xsl:value-of select="$space"/>
    <xsl:call-template name="pi-text">
      <xsl:with-param name="text" select="string(.)"/>
    </xsl:call-template>
    <xsl:value-of select="$pi-end"/>
  </xsl:template>

  <xsl:template match="text()" mode="xml-to-string">
    <xsl:call-template name="text-content">
      <xsl:with-param name="text" select="string(.)"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="element-name">
    <xsl:param name="text"/>
    <xsl:value-of select="$text"/>
  </xsl:template>

  <xsl:template name="attribute-name">
    <xsl:param name="text"/>
    <xsl:value-of select="$text"/>
  </xsl:template>

  <xsl:template name="attribute-value">
    <xsl:param name="text"/>
    <xsl:variable name="escaped-markup">
      <xsl:call-template name="escape-markup-characters">
        <xsl:with-param name="text" select="$text"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:choose>
      <xsl:when test="$attribute-delimiter = &quot;'&quot;">
        <xsl:call-template name="replace-string">
          <xsl:with-param name="text" select="$escaped-markup"/>
          <xsl:with-param name="replace" select="&quot;'&quot;"/>
          <xsl:with-param name="with" select="'&amp;apos;'"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:when test="$attribute-delimiter = '&quot;'">
        <xsl:call-template name="replace-string">
          <xsl:with-param name="text" select="$escaped-markup"/>
          <xsl:with-param name="replace" select="'&quot;'"/>
          <xsl:with-param name="with" select="'&amp;quot;'"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:call-template name="replace-string">
          <xsl:with-param name="text" select="$escaped-markup"/>
          <xsl:with-param name="replace" select="$attribute-delimiter"/>
          <xsl:with-param name="with" select="''"/>
        </xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template name="ns-prefix">
    <xsl:param name="text"/>
    <xsl:value-of select="$text"/>
  </xsl:template>

  <xsl:template name="ns-uri">
    <xsl:param name="text"/>
    <xsl:call-template name="attribute-value">
      <xsl:with-param name="text" select="$text"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="text-content">
    <xsl:param name="text"/>
    <xsl:call-template name="escape-markup-characters">
      <xsl:with-param name="text" select="$text"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="pi-target">
    <xsl:param name="text"/>
    <xsl:value-of select="$text"/>
  </xsl:template>

  <xsl:template name="pi-text">
    <xsl:param name="text"/>
    <xsl:value-of select="$text"/>
  </xsl:template>

  <xsl:template name="comment-text">
    <xsl:param name="text"/>
    <xsl:value-of select="$text"/>
  </xsl:template>

  <xsl:template name="escape-markup-characters">
    <xsl:param name="text"/>
    <xsl:variable name="ampEscaped">
      <xsl:call-template name="replace-string">
        <xsl:with-param name="text" select="$text"/>
        <xsl:with-param name="replace" select="'&amp;'"/>
        <xsl:with-param name="with" select="'&amp;amp;'"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="ltEscaped">
      <xsl:call-template name="replace-string">
        <xsl:with-param name="text" select="$ampEscaped"/>
        <xsl:with-param name="replace" select="'&lt;'"/>
        <xsl:with-param name="with" select="'&amp;lt;'"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:call-template name="replace-string">
      <xsl:with-param name="text" select="$ltEscaped"/>
      <xsl:with-param name="replace" select="']]>'"/>
      <xsl:with-param name="with" select="']]&amp;gt;'"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="replace-string">
    <xsl:param name="text"/>
    <xsl:param name="replace"/>
    <xsl:param name="with"/>
    <xsl:variable name="stringText" select="string($text)"/>
    <xsl:choose>
      <xsl:when test="contains($stringText,$replace)">
        <xsl:value-of select="substring-before($stringText,$replace)"/>
        <xsl:value-of select="$with"/>
        <xsl:call-template name="replace-string">
          <xsl:with-param name="text" select="substring-after($stringText,$replace)"/>
          <xsl:with-param name="replace" select="$replace"/>
          <xsl:with-param name="with" select="$with"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$stringText"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

Here's how you can add custom properties into the people search results.

Firstly, search for a user. Anyone will do.

Then click on Site Actions > Edit Page

Edit the People Search Core Results web part

Under the heading "Results Query Options", click the ... next to the Selected Columns and add the column:

    <Column Name="CustomPropertyName"/>

Now click on the XSL Editor... button

Look for the section: <div class="psrch-Description">

Enter this in that section:

    <xsl:with-param name="CustomPropName" select="CustomPropertyName" />

Now look for this: <xsl:template name="DisplayOfficeProfile">

Enter this in that section:

  <xsl:param name="CustomPropName" />

and:

  <xsl:if test='string-length($CustomPropName) &gt; 0'>  
   <xsl:value-of select="$CustomPropName" /> 
   -
  </xsl:if>

Now, when you click on OK, you'll get an error in the web part. Ignore that error and try to do another search to see the custom property appear in the results.

I've been searching the web for how to populate a drop down list with all available SharePoint users and although I did manage to find things, it wasn't exactly what I was looking for. The solutions I found did not list all users and it lists groups in there too (which I did not want). Anyway, after searching some more, I found something called a Contact Selector for InfoPath. The Contact Selector is an ActiveX control which is installed with InfoPath 2007. There are 2 main steps to get the Contact Selector to work however there is a third step if you plan on using the Contact Selector more than once on a single form (which I had to do in my case).

Step 1 - Add the Contact Selector to InfoPath 2007

1. In Office InfoPath 2007, on the Design Tasks pane, click Controls.
2. On the Controls pane, click Add or Remove Custom Controls.
3. In the Add or Remove Custom Controls dialog box, click Add.
4. The Add Custom Control Wizard appears.
5. Under Select a Control Type, select ActiveX Control. Click Next.
6. In the list of ActiveX controls, select Contact Selector. Click Next.
7. Under Specify Installation Options, select Don’t include in a .cab file. Click Next.
8. Under Binding property, select value. Click Next.
9. For Field or group type, select Field or group (any data type). Click Finish. Click Close. Click OK.

Step 2 - Configuring the Contact Selector

1. Open your form in Design mode in InfoPath 2007.
2. Select View-Design Tasks from the menu.
3. Click the Data Source link.
4. Right-click in the section where you want to add the control and select "Add…". Specify a name. Set the Type option to Group. Do not check the repeating check box. Click OK to save.
5. Right-click the new group added in the previous step and select "Add…". For the name, type in Person. Set the Type option to Group. Check the repeating check box. Click OK to save.
6. Right-click on the Person group and select "Add…". For the name, type in DisplayName. Click OK to save.
7. Right-click on the Person group and select "Add…". For the name, type in AccountId. Click OK to save.
8. Right-click on the Person group and select "Add…". For the name, type in AccountType. Click OK to save.
9. Drag the group created in step #5 to the location in your form where you want the Contact Selector to be displayed. A popup menu will display – select Contact Selector.
10. Open a text editor (eg. Notepad).
11. Type in the following and replace yourservername: <Context siteUrl="http://<yourservername>"/>
12. Save the file as Context.xml.
13. In InfoPath, select Tools-Data Connections from the menu.
14. Click the Add button, check the "Create a new connection to" option, and check the "Receive data" option. Click the Next button.
15. Check the "Xml document" option. Click the Next button.
16. Browse to the location where you saved the Context.xml file and open it. Click the Next button.
17. Check the "Include the data as a resource file in the form template or template part" option. Click the Next button.
18. Enter the name Context. Click the Finish button.
19. Save the form.
20. Publish the form.

Now if you try adding a second Contact Selector and publish the form, you'll get an error.

To be able to use more than 1 Contact Selector, you need to complete Step 3.

Step 3 - Using multiple Contact Selectors in a single form

1. Complete Step 2.4 above for every contact selector you want to add.
2. Right click on the Person group and click on "Reference"
3. A window should pop up. Select the group that you created above in Step 3.1
4. Drag and drop the group to the location where you want the Contact Selector to appear on your form. When the popup menu is displayed, select Contact Selector

And there you have it. You now have the ability to select users from SharePoint. From here, you can create workflows that involve these selected users from SharePoint Designer by setting these fields as being available in SharePoint sites (when publishing), but that's another story.

What I needed to do was to sort a list of dates and corresponding names in order of date. Problem was that sometimes the dates duplicate and as a result, a standard SortedList would crash (since keys need to be unique). Anyway, here's a workaround to that problem. We create a new class for the project as follows:

    public class ComparableDateTime : IComparable
    {
        private DateTime mDT;

        public int CompareTo(object obj)
        {
            if (mDT.Ticks < ((ComparableDateTime)obj).mDT.Ticks) return -1;
            return 1;
        }

        public ComparableDateTime(DateTime myDate)
        {
            mDT = myDate;
        }
    }

Then once we have the class, we can declare a SortedList with that class:

using System.Collections.Generic;

SortedList<ComparableDateTime, string> mySortedList = new SortedList<ComparableDateTime,string>();

DateTime someDate = DateTime.Today;

mySortedList.Add(new ComparableDateTime(someDate,"someString");
mySortedList.Add(new ComparableDateTime(someDate,"someString2");

for (int i = 0; i < mySortedList.Count; i++)
{
    writer.Write(mySortedList.Values[i].ToString());
}